app-crypt/gnupg: Add 2.1.16 based on 9999 ebuild
authorKristian Fiskerstrand <kf@sumptuouscapital.com>
Fri, 18 Nov 2016 22:11:00 +0000 (23:11 +0100)
committerKristian Fiskerstrand <kf@sumptuouscapital.com>
Fri, 18 Nov 2016 22:11:00 +0000 (23:11 +0100)
app-crypt/gnupg/Manifest
app-crypt/gnupg/gnupg-2.1.16.ebuild [new file with mode: 0644]
app-crypt/gnupg/gnupg-9999.ebuild
app-crypt/gnupg/metadata.xml

index 85ef965..a68184b 100644 (file)
@@ -1,5 +1,5 @@
 AUX gnupg-9999-tests-pkits-Makefile.am-Remove-failing-tests.patch 821 SHA256 5ab4c085d499a0d22e504d8e81f2317e1cf4ea59dba52fa12de213a829e3f40a SHA512 f3006885aaa69c51d9f6c6b61888518783c1bb95ce7ae7985cbaf5c1a9c858115f8e8446b3cfc6169a645f3705464728e3a81e5c060f5ccda16055ae6a199cf8 WHIRLPOOL 6d0dad38ee411f200b6fbff73d2f266c46335822eca158b1e837f1a8b79555b38df8be6bdfef70860e0355e0f6c2a51fdd26498a7fe13a219d2bcbc03673bd2d
-DIST gnupg-2.1.15.tar.bz2 5723689 SHA256 c28c1a208f1b8ad63bdb6b88d252f6734ff4d33de6b54e38494b11d49e00ffdd SHA512 69c943e853e1a37e8b17b3bc34e1503f14bc8f189fa9f3ac6644bcc98ccce6eaef64da20ff9dd1c8de3a7789ea577167984ccf3ac286cac50752e6f7c2f42ab1 WHIRLPOOL 4c5a8cd4e8b7196f4a355ce7739cf6e23c43817414e10bbba219117e4e51c4c618ffb5dbce27cb836a2171eda58e003d5ddf78d4af09a813c2a1729963413151
-EBUILD gnupg-2.1.15.ebuild 3555 SHA256 a3096d4e2d74ff3a7ecc890169b166c1ccdf1aa0889499820da95a925ef0aca6 SHA512 53a0f18c6e2444484449e5bc3cbefa6e9b49f6b020f18d461bca8bc248efd92fab5a9bc07b6247119c2d5924ce696699e659638f8fe4c4f2383a78e8ba46b3cb WHIRLPOOL 906b05a602dbc482cc111c7676a73dc2c9743a2a4faa565c5e32b897f8d1ab43f02c02eb66560e9d8ec7c7f10d245a213a18810aa8f6b6a4edf145ac64f8c301
-EBUILD gnupg-9999.ebuild 3482 SHA256 f3d838cb3bc861abeb2b505d4557706b3997b75e8ff1b6fc62d558c8c9e95988 SHA512 6559461d2a8ba1c89124af7ceb3a05e22d8f83ad38fb5c4796dae13dcaf723780004b89834451719a781a095fe89ebd3dd942581d9f2a87f3f4a04ca7022e407 WHIRLPOOL afdcd1c1badab773fcc549f22259f4f0ddf4694b447489bb6da0aa494764745db3dac41b5b46a9765d5b102a5f71e435b3ee615df66d269252ab5a3075d6cf0a
-MISC metadata.xml 1366 SHA256 cb2997a736840b0db98ca7ea5328a40b4d53375441fb05047641fe2ff147822b SHA512 9c0fda3cc3bcbbd3bcc883df0b39a4e9c4dd058ef3ef4751699c39270bdbe6dbc9b049d91c3fe78689c7a878eb483f7cfe1641e8e4421535ca3b6a56e06c13fe WHIRLPOOL 44a243cc732333007723a37214b34e8f26dae2f778d34880db8f6ccb235b24d2f96c3e0583aeb74a982f54e88b7df9a4fea3291a897c6ddfdba3b594e29a70c1
+DIST gnupg-2.1.16.tar.bz2 5840687 SHA256 49b9a6a6787ad00d4d2d69d8c7ee8905923782583f06078a064a0c80531d8844 SHA512 dbac27106e7800e30f286c3fd83ffab85d2b0acf29d6715ce3e388bfbece2a7deb19ebfe897c445d7a3d6d63e01560b9461567566e936504bc5d6cabe1444af7 WHIRLPOOL e6fe2e39deb1ce5ba41c8d160721c64bc3846c2f5d42027a45d6d3e3bd45b6acba38c41923af1165312c9e993d63f28c6fd6616e6f659f6eb4e6d3899d42897b
+EBUILD gnupg-2.1.16.ebuild 3483 SHA256 13f2e79c9b49bb89cf138da1aa38245f7c796d6c685ccd11410a8895a14ff43e SHA512 205947de0cc8ddbbb4a2d03889846f346d0d12858b49ebf22b9eef6227f4c411ee159fc9c2033de98889a5e7d78bc84da5d30b05e4768195a40fb8e2ddebc9a4 WHIRLPOOL 24faaeee9224276d558cf71b0269672d004575fa56ba93a9aa0366531ebc9a06a1c9aa9da27345514d053340fed818594e2a704dc34990cfbda422f131e2c1fc
+EBUILD gnupg-9999.ebuild 3483 SHA256 13f2e79c9b49bb89cf138da1aa38245f7c796d6c685ccd11410a8895a14ff43e SHA512 205947de0cc8ddbbb4a2d03889846f346d0d12858b49ebf22b9eef6227f4c411ee159fc9c2033de98889a5e7d78bc84da5d30b05e4768195a40fb8e2ddebc9a4 WHIRLPOOL 24faaeee9224276d558cf71b0269672d004575fa56ba93a9aa0366531ebc9a06a1c9aa9da27345514d053340fed818594e2a704dc34990cfbda422f131e2c1fc
+MISC metadata.xml 1272 SHA256 590bcdffd8aa11cd5f63d5905c0b3d9d42ba57d8239defe3e63f8d15e688da2f SHA512 5cd37a92f37a881df8708295def5a0e969a09a5c1ddc4a811abb744fdd723affee10a17bda55258f27b5b0d3173a9dc5b3c0a1d30caa2767862d18b444981f5e WHIRLPOOL cdcae44837882087e2ecb2dde07791efca97afb874173c30d770cad27576c399761c3119097ac1ee7ee0ce80f72f521204e5516ca6c48bcf4993dbd38fff97a1
diff --git a/app-crypt/gnupg/gnupg-2.1.16.ebuild b/app-crypt/gnupg/gnupg-2.1.16.ebuild
new file mode 100644 (file)
index 0000000..82b1d6a
--- /dev/null
@@ -0,0 +1,151 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+inherit eutils flag-o-matic toolchain-funcs
+
+if [[ ${PV} == *9999* ]]; then
+       inherit autotools git-2
+fi
+
+DESCRIPTION="The GNU Privacy Guard, a GPL OpenPGP implementation"
+HOMEPAGE="http://www.gnupg.org/"
+LICENSE="GPL-3"
+
+if [[ ${PV} != *9999* ]]; then
+       MY_P="${P/_/-}"
+       SRC_URI="mirror://gnupg/gnupg/${MY_P}.tar.bz2"
+       KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+else
+       KEYWORDS=""
+       EGIT_REPO_URI="git://git.gnupg.org/${PN}.git"
+fi
+
+SLOT="0"
+IUSE="bzip2 doc +gnutls ldap nls readline selinux +smartcard tofu tools usb wks-server"
+
+COMMON_DEPEND_LIBS="
+       >=dev-libs/npth-1.2
+       >=dev-libs/libassuan-2.4.3
+       >=dev-libs/libgcrypt-1.7.3
+       >=dev-libs/libgpg-error-1.24
+       >=dev-libs/libksba-1.3.4
+       >=net-misc/curl-7.10
+       gnutls? ( >=net-libs/gnutls-3.0:0= )
+       sys-libs/zlib
+       ldap? ( net-nds/openldap )
+       bzip2? ( app-arch/bzip2 )
+       readline? ( sys-libs/readline:0= )
+       smartcard? ( usb? ( virtual/libusb:0 ) )
+       tofu? ( >=dev-db/sqlite-3.7 )
+       "
+COMMON_DEPEND_BINS="app-crypt/pinentry
+                  !app-crypt/dirmngr"
+
+# Existence of executables is checked during configuration.
+DEPEND="${COMMON_DEPEND_LIBS}
+       ${COMMON_DEPEND_BINS}
+       nls? ( sys-devel/gettext )
+       doc? ( sys-apps/texinfo )"
+
+RDEPEND="${COMMON_DEPEND_LIBS}
+       ${COMMON_DEPEND_BINS}
+       selinux? ( sec-policy/selinux-gpg )
+       nls? ( virtual/libintl )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+       default
+       if [[ ${PV} == *9999* ]]; then
+               epatch "${FILESDIR}"/${P}-tests-pkits-Makefile.am-Remove-failing-tests.patch
+       fi
+
+       epatch_user
+       if [[ ${PV} == *9999* ]]; then
+               autoreconf || die
+               ./autogen.sh || die
+       fi
+}
+
+src_configure() {
+       local myconf=()
+
+       if use smartcard; then
+               myconf+=(
+                       --enable-scdaemon
+                       $(use_enable usb ccid-driver)
+               )
+       else
+               myconf+=( --disable-scdaemon )
+       fi
+
+       if use elibc_SunOS || use elibc_AIX; then
+               myconf+=( --disable-symcryptrun )
+       else
+               myconf+=( --enable-symcryptrun )
+       fi
+
+       # glib fails and picks up clang's internal stdint.h causing weird errors
+       [[ ${CC} == *clang ]] && \
+               export gl_cv_absolute_stdint_h=/usr/include/stdint.h
+
+       maintainer_mode=""
+
+       if [[ ${PV} == *9999* ]]; then
+               maintainer_mode+="--enable-maintainer-mode "
+       fi
+
+       econf \
+               ${maintainer_mode} \
+               --docdir="${EPREFIX}/usr/share/doc/${PF}" \
+               --enable-gpg \
+               --enable-gpgsm \
+               --enable-large-secmem \
+               --without-adns \
+               "${myconf[@]}" \
+               $(use_enable bzip2) \
+               $(use_enable gnutls) \
+               $(use_with ldap) \
+               $(use_enable nls) \
+               $(use_with readline) \
+               $(use_enable tofu) \
+               $(use_enable tools) \
+               $(use_enable wks-server wks-tools) \
+               CC_FOR_BUILD="$(tc-getBUILD_CC)"
+}
+
+src_compile() {
+       default
+
+       if use doc; then
+               cd doc
+               emake html
+       fi
+}
+
+src_install() {
+       default
+
+       use tools && dobin tools/{convert-from-106,gpg-check-pattern} \
+               tools/{gpg-zip,gpgconf,gpgsplit,lspgpot,mail-signed-keys} \
+               tools/make-dns-cert
+       emake DESTDIR="${D}" -f doc/Makefile uninstall-nobase_dist_docDATA
+
+       dodoc ChangeLog NEWS README THANKS TODO VERSION doc/FAQ doc/DETAILS \
+               doc/HACKING doc/TRANSLATE doc/OpenPGP doc/KEYSERVER doc/help*
+
+       dosym gpg2 /usr/bin/gpg
+       dosym gpgv2 /usr/bin/gpgv
+       echo ".so man1/gpg2.1" > "${ED}"/usr/share/man/man1/gpg.1
+       echo ".so man1/gpgv2.1" > "${ED}"/usr/share/man/man1/gpgv.1
+
+       dodir /etc/env.d
+       echo "CONFIG_PROTECT=/usr/share/gnupg/qualified.txt" >> "${ED}"/etc/env.d/30gnupg
+
+       if use doc; then
+               dohtml doc/gnupg.html/* doc/*.png
+       fi
+}
index 1a0bccd..82b1d6a 100644 (file)
@@ -17,7 +17,7 @@ LICENSE="GPL-3"
 if [[ ${PV} != *9999* ]]; then
        MY_P="${P/_/-}"
        SRC_URI="mirror://gnupg/gnupg/${MY_P}.tar.bz2"
-       KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s39 ~sh ~sparc ~x86"
+       KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
 else
        KEYWORDS=""
        EGIT_REPO_URI="git://git.gnupg.org/${PN}.git"
index c651aea..b921e32 100644 (file)
@@ -21,9 +21,6 @@
       Bring in <pkg>dev-libs/libusb</pkg> as a dependency; enable
       scdaemon.
     </flag>
-       <flag name="system-cert-store">
-         Use gnutls system TLS cert store for hkps access
-       </flag>
     <flag name="usb">
       Build direct CCID access for scdaemon; requires
       <pkg>dev-libs/libusb</pkg>.